
**Quarter-over-quarter growth**

Quarter-over-quarter compares a time period to its equivalent in the previous quarter. In this example, data is available until August 2009. For this reason, Sales PQ shows numbers related to Q3-2009 considering only transactions before the second month of Q2-2009. Figure 4 shows that the Sales Amount of Q2-2009 is 2,618,644.64, whereas Sales PY for Q3-2009 returns 1,746,058.45. This is because the measure takes into account the sales of only the first two months of Q2-2009.



Sales PQ removes all the filters from the Date table; it filters the Year Quarter Number column using the previous quarter, and with [**VALUES**](https://dax.guide/values/?aff=dax-patterns) which retrieves the months visible in the filter context it filters the Month In Quarter Number column. This way, any direct or indirect selection of months is applied to the previous quarter:

Sales PQ :=

VAR CurrentYearQuarterNumber = SELECTEDVALUE ( 'Date'[Year Quarter Number] )

VAR PreviousYearQuarterNumber = CurrentYearQuarterNumber - 1

VAR Result =

    CALCULATE (

        [Sales Amount],

        REMOVEFILTERS ( 'Date' ),

        'Date'[Year Quarter Number] = PreviousYearQuarterNumber,

        VALUES ( 'Date'[Month In Quarter Number] )

    )

RETURN

    Result

Quarter-over-quarter growth is computed as an amount in Sales QOQ and as a percentage in Sales QOQ %. Both measures use Sales PQ to guarantee a fair comparison:

Sales QOQ :=

VAR ValueCurrentPeriod = [Sales Amount]

VAR ValuePreviousPeriod = [Sales PQ]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod )

            && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales QOQ % :=


DIVIDE (

    [Sales QOQ],

    [Sales PQ]

)

Quarter-over-quarter compares a period with the equivalent period in the previous quarter.



Sales PQ means previous quarter.

Sales QOQ – sales quarter over quarter.

Sales PQ uses [**DATEADD**](https://dax.guide/dateadd/?aff=dax-patterns) and filters Date[DateWithSales] to guarantee a fair comparison with the last period with data. The quarter-over-quarter growth is computed as an amount in Sales QOQ and as a percentage in Sales QOQ %. Both measures use Sales PQ to guarantee the same fair comparison:

Sales PQ :=

IF (

    [ShowValueForDates],

    CALCULATE (

        [Sales Amount],

        CALCULATETABLE (

            DATEADD ( 'Date'[Date], -1, QUARTER ),

            'Date'[DateWithSales] = TRUE

        )

    )

)

Sales QOQ :=

VAR ValueCurrentPeriod = [Sales Amount]

VAR ValuePreviousPeriod = [Sales PQ]

VAR Result =

    IF (

        NOT ISBLANK ( ValueCurrentPeriod ) && NOT ISBLANK ( ValuePreviousPeriod ),

        ValueCurrentPeriod - ValuePreviousPeriod

    )

RETURN

    Result

Sales QOQ % :=

DIVIDE (

    [Sales QOQ],

    [Sales PQ]

)